UDF > GUI > GuiStatusBar >

_GUICtrlStatusBar_GetTextFlags

Obtient les flags de longueur de texte pour une partie donn�e

#include <GuiStatusBar.au3>
_GUICtrlStatusBar_GetTextFlags ( $hWnd, $iPart )

Param�tres

$hWnd Handle du contr�le StatusBar
$iPart Index, de base 0, de la partie

Valeur de retour

Retourne dans le mot de poids faible la longueur en caract�res, du texte. Le mot de poids fort indique le type d'op�ration utilis� pour dessiner le texte. Le type peut �tre l'une des valeurs suivantes:
    0 - Le texte est dessin� avec une bordure qui appara�t plus bas que le niveau de la fen�tre
    $SBT_NOBORDERS - Le texte est dessin� sans bordure
    $SBT_OWNERDRAW - Le texte est dessin� par la fen�tre parent
    $SBT_POPOUT - Le texte est dessin� avec une bordure qui appara�t plus haut que le niveau de la fen�tre
    $SBT_RTLREADING - Le texte est affich� dans la direction oppos�e au texte de la fen�tre parent

En relation

_GUICtrlStatusBar_GetTextLength, _GUICtrlStatusBar_GetTextLengthEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hStatus
    Local $aParts[3] = [75, 150, -1]

    ; Cr�e une GUI
    $hGUI = GUICreate("(Exemple 1) StatusBar Get Text Flags", 400, 300)
    $hStatus = _GUICtrlStatusBar_Create($hGUI)

    ; Cr�e un contr�le memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 274, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; D�finit des parties
    _GUICtrlStatusBar_SetParts($hStatus, $aParts)
    _GUICtrlStatusBar_SetText($hStatus, "Part 1", 0, $SBT_POPOUT)
    _GUICtrlStatusBar_SetText($hStatus, "Part 2", 1, $SBT_NOBORDERS)
    _GUICtrlStatusBar_SetText($hStatus, "Part 3", 2, $SBT_NOTABPARSING)

    ; Obtient des informations sur le texte
    For $iI = 0 To _GUICtrlStatusBar_GetCount($hStatus) - 1
        MemoWrite("Part " & $iI & " text flags .: " & _GUICtrlStatusBar_GetTextFlags($hStatus, $iI))
        MemoWrite("Part " & $iI & " text length : " & _GUICtrlStatusBar_GetTextLength($hStatus, $iI))
        MemoWrite("Part " & $iI & " text length : 0x" & Hex(_GUICtrlStatusBar_GetTextLengthEx($hStatus, $iI)))
        MemoWrite()
    Next

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit un message dans le contr�le memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite