UDF > GUI > GuiToolbar >

_GUICtrlToolbar_InsertMarkHitTest

R�cup�re les informations de marque d'insertion pour un point

#include <GuiToolbar.au3>
_GUICtrlToolbar_InsertMarkHitTest ( $hWnd, $iX, $iY )

Param�tres

$hWnd Handle du contr�le barre d'outils
$iX Position X par rapport � la zone client
$iY Position Y par rapport � la zone client

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Index, de base 0, de la marque d'insertion ou -1 pour aucune marque d'insertion
    [1] - D�finit la position d'insertion. Cela peut �tre l'une des valeurs suivantes:
        0 - A gauche
        1 - A droite
        2 - Sur le fond de la barre d'outils

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar, $aStrings[4], $aRect, $aMark
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Cr�e une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps syst�me standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des cha�nes
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; D�finit la marque d'insertion
    _GUICtrlToolbar_SetInsertMark($hToolbar, 1, 1)

    ; Fait le test de position de la marque d'insertion 1
    $aMark = _GUICtrlToolbar_InsertMarkHitTest($hToolbar, 0, 0)
    MemoWrite("Index ........: " & $aMark[0])
    MemoWrite("Relationship .: " & $aMark[1])

    ; Fait le test de position de la marque d'insertion 2
    $aRect = _GUICtrlToolbar_GetButtonRect($hToolbar, $e_idSave)
    $aMark = _GUICtrlToolbar_InsertMarkHitTest($hToolbar, $aRect[0], $aRect[1])
    MemoWrite("Index ........: " & $aMark[0])
    MemoWrite("Relationship .: " & $aMark[1])

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contr�le memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite