UDF > GUI > GuiToolbar >

_GUICtrlToolbar_SetButtonStyle

D�finit les indicateurs de style d'un bouton

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetButtonStyle ( $hWnd, $iCommandID, $iStyle )

Param�tres

$hWnd Handle du contr�le barre d'outils
$iCommandID ID de commande du bouton
$iStyle Style du bouton. Peut �tre l'un ou plusieurs des �l�ments suivants:
    $BTNS_AUTOSIZE - Le contr�le barre d'outils ne doit pas d�finir la largeur standard du bouton
    $BTNS_CHECK - Bascule entre press� et non press�
    $BTNS_CHECKGROUP - Bouton qui reste enfonc� jusqu'� ce qu'un autre bouton dans le groupe soit press�
    $BTNS_DROPDOWN - bouton de style d�roulant qui permet d'afficher une liste
    $BTNS_GROUP - Bouton qui reste enfonc� jusqu'� ce qu'un autre bouton dans le groupe soit press�
    $BTNS_NOPREFIX - Le texte du bouton n'aura pas de pr�fixe acc�l�rateur
    $BTNS_SEP - S�parateur
    $BTNS_SHOWTEXT - Le texte du bouton doit �tre affich�
    $BTNS_WHOLEDROPDOWN - Le bouton a une fl�che d�roulante

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

En relation

_GUICtrlToolbar_GetButtonStyle

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Cr�e une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps syst�me standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Set Save button style
    _GUICtrlToolbar_SetButtonStyle($hToolbar, $e_idSave, $BTNS_CHECK)

    ; Affiche le style du bouton Save
    MemoWrite("Save button style: " & _GUICtrlToolbar_GetButtonStyle($hToolbar, $e_idSave))

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contr�le memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite