UDF > GUI > GuiTreeView >

_GUICtrlTreeView_Expand

D�veloppe ou r�duit la liste des noeuds enfants du noeud parent sp�cifi�, s'il y en a

#include <GuiTreeView.au3>
_GUICtrlTreeView_Expand ( $hWnd [, $hItem = 0 [, $bExpand = True]] )

Param�tres

$hWnd ID/handle du contr�le
$hItem [optionnel] Handle du noeud
$bExpand [optionnel] D�veloppe ou R�duit; utiliser les valeurs suivantes :
    True - D�veloppe les noeuds enfants
    False - R�duit les noeuds enfants

Valeur de retour

Aucune.

En relation

_GUICtrlTreeView_ExpandedOnce, _GUICtrlTreeView_GetExpanded

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $aidItem[5], $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Expand", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 4
        $aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Expand All")
    _GUICtrlTreeView_Expand($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Collapse All")
    _GUICtrlTreeView_Expand($idTreeView, 0, False)

    MsgBox($MB_SYSTEMMODAL, "Information", "Expand item 0")
    _GUICtrlTreeView_Expand($idTreeView, $aidItem[0])

    MsgBox($MB_SYSTEMMODAL, "Information", "Collapse item 0")
    _GUICtrlTreeView_Expand($idTreeView, $aidItem[0], False)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example