UDF > GUI > GuiToolTip >

_GUIToolTip_AddTool

Enregistre un �l�ment d�clencheur d'info-bulle

#include <GuiToolTip.au3>
_GUIToolTip_AddTool ( $hTool, $hWnd, $sText [, $iID = 0 [, $iLeft = 0 [, $iTop = 0 [, $iRight = 0 [, $iBottom = 0 [, $iFlags = Default [, $iParam = 0]]]]]]] )

Param�tres

$hTool Handle du contr�le info-bulle (retourn� par _GUIToolTip_Create.)
$hWnd Handle de la fen�tre qui contient l'�l�ment, ou 0
$sText Texte pour le contr�le info-bulle. Voir Remarques.
$iID [optionnel] Identifiant de l'�l�ment d�clencheur, ou handle Window du contr�le auquel l'�l�ment doit �tre assign�
$iLeft [optionnel] Coordonn�e X du coin sup�rieur gauche du rectangle
$iTop [optionnel] Coordonn�e Y du coin sup�rieur gauche du rectangle
$iRight [optionnel] Coordonn�e X du coin inf�rieur droit du rectangle
$iBottom [optionnel] Coordonn�e Y du coin inf�rieur droit du rectangle
$iFlags [optionnel] Flags qui contr�lent l'affichage des info-bulle:
    $TTF_IDISHWND - Indique que $iID est le handle d'une fen�tre ou d'un contr�le, � la place de l'identifiant de l'�l�ment d�clencheur
    $TTF_CENTERTIP - Centre l'info-bulle au dessous du contr�le sp�cifi� par $iID
    $TTF_RTLREADING - Indique que le texte sera affich� dans la direction oppos�e de la fen�tre parente (voir Remarques)
    $TTF_SUBCLASS - Indique que le contr�le doit prendre le dessus sur la fen�tre de l'�l�ment
    $TTF_TRACK - Positionne le cadre de l'info-bulle � c�t� de l'�l�ment qui lui correspond
    $TTF_ABSOLUTE - Positionne le cadre aux m�mes coordonn�es que celles fournies par TTM_TRACKPOSITION. (Voir remarques)
    $TTF_TRANSPARENT - Force le contr�le � transmettre les messages de la souris � la fen�tre parente
    $TTF_PARSELINKS - Indique que les liens dans le texte du contr�le doivent �tre affich�s en tant que liens

Par d�faut = BitOr($TTF_SUBCLASS, $TTF_IDISHWND)
Les constantes sont d�finies dans ToolTipConstants.au3
$iParam [optionnel] Valeur d�finie par l'application qui est associ�e � l'�l�ment d�clencheur

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Remarques

Si un rappel de notification est n�cessaire, vous devez d�finir $sText = -1 (LPSTR_TEXTCALLBACK).

Si vous utilisez le flag $TTF_IDISHWND, alors les coordonn�es $iLeft, $iTop, $$iRight et iBottom sont ignor�es.

Si vous utilisez le flag $TTF_ABSOLUTE, il doit �tre utilis�e avec le param�tre $TTF_TRACK.
Les fen�tres normales affichent le texte de gauche � droite (LTR). Windows peut afficher des langues comme l'h�breu ou l'arabe qui lisent de droite � gauche (RTL). Normalement, le texte de l'info-bulle s'affiche dans le m�me sens que le texte dans sa fen�tre parent. Si $TTF_RTLREADING est activ�, le texte de l'info-bulle sera lu dans le sens oppos� par rapport au texte de la fen�tre parent.

En relation

_GUIToolTip_DelTool

Exemples

Exemple 1

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Cr�e un contr�le info-bulle avec les param�tres par d�faut
    Local $hToolTip = _GUIToolTip_Create(0)

    ; Ajoute un �l�ment d�clencheur au contr�le info-bulle
    _GUIToolTip_AddTool($hToolTip, 0, "This is a ToolTip", $hButton)
    GUISetState(@SW_SHOW)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    ; D�truit le contr�le info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example

Exemple 2

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <StaticConstants.au3>

; Cet exemple montre comment ajouter un outil, il n'assigne pas l'outil � un contr�le, justa � une zone de la GUI
Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200) 
    ; Cr�e des cadres pour indiquer o� l'info-bulle s'affichera lorsque la souris sera �
    ; l'emplacement correct dans la GUI, ces cadres ne sont pas assign�s � une info-bulle
    ; Ces cadres sont SEULEMENT pour la repr�sentation visuelle de l'endroit o� l'info-bulle s'affichera,
    ; Ils ne sont pas n�cessaires pour afficher l'info-bulle.
    GUICtrlCreateLabel("", 10, 10, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contr�le label doit �tre d�sactiv�, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("", 10, 84, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contr�le label doit �tre d�sactiv�, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("", 169, 10, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contr�le label doit �tre d�sactiv�, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.    
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("", 169, 84, 160, 75, $SS_ETCHEDFRAME)
    ; Ce contr�le label doit �tre d�sactiv�, sinon l'info-bulle ne s'affichera pas quand la 
    ; souris le survolera.
    GUICtrlSetState(-1, $GUI_DISABLE)
    Local $idButton = GUICtrlCreateButton("Ceci est un bouton", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; Cr�e un contr�le info-bulle avec les param�tres par d�faut
    Local $hToolTip = _GUIToolTip_Create(0)

    ; Ajoute 4 �l�ments d�clencheurs au contr�le info-bulle, ces �l�ments sont cr��s en utilisant des positions sur la GUI
    ; plut�t qu'en les assignant � un contr�le sp�cifique
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin sup�rieur gauche", 0, 10, 10, 168, 85, $TTF_SUBCLASS)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin sup�rieur droit", 0, 168, 10, 328, 85, $TTF_SUBCLASS)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin inf�rieur gauche", 0, 10, 85, 168, 160, $TTF_SUBCLASS)
    _GUIToolTip_AddTool($hToolTip, $hGUI, "Coin inf�rieur droit", 0, 168, 85, 328, 160, $TTF_SUBCLASS)
    ; Ajoute un �l�ment d�clencheur au contr�le info-bulle qui est assign� au contr�le bouton
    _GUIToolTip_AddTool($hToolTip, 0, "This tooltip belongs to the button", $hButton)
    GUISetState(@SW_SHOW)

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    ; D�truit le contr�le info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example