UDF > NetShare >

_Net_Share_ConnectionEnum

�num�re toutes les connexions � une ressource partag�e

#include <NetShare.au3>
_Net_Share_ConnectionEnum ( $sServer, $sQualifier )

Param�tres

$sServer Cha�ne qui sp�cifie le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'ex�cutera.
Si ce param�tre est vide l'ordinateur local est utilis�.
$sQualifier Indique un nom de partage ou le nom de l'ordinateur qui vous int�resse.
S'il s'agit d'un nom de partage, alors toutes les connexions faites � ce nom de partage sont list�s.
S'il s'agit d'un nom d'ordinateur, la fonction liste toutes les connexions faites � partir de l'ordinateur vers le serveur sp�cifi�.

Valeur de retour

Succ�s: Retourne un tableau avec le format suivant:
    [0][0] - Nombre d'entr�es dans le tableau
    [1][0] - Num�ro d'identification de la connexion
    [1][1] - Type de connexion. Peut �tre une combinaison de:
        $STYPE_DISKTREE - Lecteur de disque
        $STYPE_PRINTQ - File d'attente d'impression
        $STYPE_DEVICE - P�riph�rique de communication
        $STYPE_IPC - IPC
        $STYPE_SPECIAL - Partage sp�cifique r�serv�e aux IPC$ ou � l'administration � distance du serveur
        $STYPE_TEMPORARY - Partage temporaire
    [1][2] - Nombre de fichiers actuellement ouvert � la suite de la connexion
    [1][3] - Nombre d'utilisateurs sur la connexion
    [1][4] - Nombre de secondes �coul�es depuis que la connexion a �t� �tablie
    [1][5] - Si le partage de la ressource serveur s'ex�cute avec la s�curit� au niveau de l'utilisateur, ce membre d�crit quel utilisateur a fait la connexion. Si le serveur est en cours d'ex�cution avec la s�curit� au niveau partage, ce membre d�crit quel ordinateur a fait la connexion.
    [1][6] - Indique le nom de partage de la ressource partag�e du serveur ou le nom de l'ordinateur du client
�chec: D�finit @error <> 0.

Remarque

Les droits d'Administrateur, d'Op�rateur de serveur ou d'impression ou membre du groupe Power User sont n�cessaires pour ex�cuter cette fonction

En relation

_Net_Share_FileEnum, _Net_Share_SessionEnum, _Net_Share_ShareEnum

Voir aussi

Consultez NetConnectionEnum dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $sShare, $aInfo

    ; Cr�e une GUI
    GUICreate("NetShare", 400, 300)

    ; Cr�e un contr�le Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient le serveur et les informations � partager
    $sServer = InputBox("NetWork Demo", "Entrez le nom du serveur:", "\\MyServer", "", 200, 130)
    If @error Then Exit
    $sShare = InputBox("NetWork Demo", "Entrez le nom de partage:", "MyShare", "", 200, 130)
    If @error Then Exit

    ; �num�re les connexions r�seau
    $aInfo = _Net_Share_ConnectionEnum($sServer, $sShare)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Connection ID ...........: " & $aInfo[$iI][0])
        MemoWrite("Connection type..........: " & _Net_Share_ResourceStr($aInfo[$iI][1]))
        MemoWrite("Number of files open ....: " & $aInfo[$iI][2])
        MemoWrite("Number of users .........: " & $aInfo[$iI][3])
        MemoWrite("Connection time .........: " & $aInfo[$iI][4])
        MemoWrite("Username ................: " & $aInfo[$iI][5])
        MemoWrite("Network name ............: " & $aInfo[$iI][6])
        MemoWrite()
    Next

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contr�le Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite