UDF > NetShare >

_Net_Share_FileGetInfo

Obtient des informations sur une ouverture particuli�re d'une ressource de serveur

#include <NetShare.au3>
_Net_Share_FileGetInfo ( $sServer, $iFileID )

Param�tres

$sServer Indique le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'ex�cutera.
Si ce param�tre est vide, l'ordinateur local est utilis�.
$iFileID Identifiant du fichier de la ressource dont vous voulez obtenir des informations.
La valeur de ce param�tre doit avoir �t� obtenu dans un appel d'�num�ration pr�c�dente.

Valeur de retour

Succ�s: Retourne un tableau avec le format suivant:
    [0] - Num�ro d'ID attribu� � la ressource lorsqu'elle est ouverte
    [1] - Autorisations d'acc�s associ�s � l'ouverture de l'application:
        1 - Autorisation d'acc�s pour lire une ressource et ex�cuter la ressource
        2 - Autorisation d'acc�s pour �crire dans une ressource.
        4 - Autorisation d'acc�s pour cr�er une ressource
        8 - Autorisation d'acc�s pour l'ex�cution
        16 - Autorisation d'acc�s pour la suppression
        32 - Autorisation d'acc�s pour modifier des attributs
        64 - Autorisation d'acc�s pour changer ACL
    [2] - Contient le nombre de verrous de fichier sur la ressource
    [3] - Indique le chemin de la ressource ouverte
    [4] - Sp�cifie l'utilisateur ou l'ordinateur qui a ouvert la ressource
�chec: D�finit @error <> 0.

Remarque

Administrateur, Op�rateur de serveur ou d'impression ou l'appartenance au groupe Power User est n�cessaire pour ex�cuter cette fonction.

En relation

_Net_Share_SessionGetInfo, _Net_Share_ShareGetInfo

Voir aussi

Consultez NetFileGetInfo dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $aFile, $aInfo

    ; Cr�e une GUI
    GUICreate("NetShare", 400, 300)

    ; Cr�e un contr�le Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient le serveur et le nom de partage
    $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
    If @error Then Exit

    ; �num�re les fichiers ouverts sur le serveur
    $aFile = _Net_Share_FileEnum($sServer)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aFile[0][0])
    MemoWrite()

    ; Obtient des informations pour chaque fichier ouvert (comme les infos de $aFile)
    For $iI = 1 To $aFile[0][0]
        $aInfo = _Net_Share_FileGetInfo($sServer, $aFile[$iI][0])
        MemoWrite("Error ...................: " & @error)
        MemoWrite("File permissions ........: " & _Net_Share_PermStr($aInfo[1]))
        MemoWrite("File locks ..............: " & $aInfo[2])
        MemoWrite("File path ...............: " & $aInfo[3])
        MemoWrite("File user ...............: " & $aInfo[4])
        MemoWrite()
    Next

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contr�le Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite