UDF > NetShare >

_Net_Share_ShareCheck

V�rifie si un serveur partage un p�riph�rique

#include <NetShare.au3>
_Net_Share_ShareCheck ( $sServer, $sShare )

Param�tres

$sServer Indique le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'ex�cutera.
Si ce param�tre est vide, l'ordinateur local est utilis�.
$sShare Indique le nom du p�riph�rique dont il faut v�rifier l'acc�s partag�

Valeur de retour

Succ�s: Retourne le type du p�riph�rique partag�. Doit �tre une combinaison de:
    $STYPE_DISKTREE - Lecteur de disque
    $STYPE_PRINTQ - File d'attente d'impression
    $STYPE_DEVICE - P�riph�rique de communication
    $STYPE_IPC - IPC
    $STYPE_SPECIAL - Partage sp�cifique r�serv�e aux IPC$ ou � l'administration � distance du serveur
    $STYPE_TEMPORARY - Partage temporaire
�chec: -1 - Le partage n'existe pas

Remarque

Aucune appartenance � un groupe sp�cial s'impose pour ex�cuter cette fonction avec succ�s.

En relation

_Net_Share_ShareAdd, _Net_Share_ShareDel

Voir aussi

Consultez NetShareCheck dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

#RequireAdmin ; n�cessaire pour _Net_Share_ShareAdd()

Global $g_idMemo

Example()

Func Example()
    Local $iI, $aInfo
    Local Const $sShareName = "AutoIt Share"

    ; Cr�e une GUI
    GUICreate("NetShare", 400, 300)

    ; Cr�e un contr�le Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Teste si le partage existe
    If _Net_Share_ShareCheck(@ComputerName, $sShareName) = -1 Then
        ; Cr�e un partage sur l'ordinateur local
        _Net_Share_ShareAdd(@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
        If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur dans ShareAdd: " & @error)
        MemoWrite("Partage ajout�")
    Else
        MemoWrite("Le partage existe")
    EndIf

    ; Affiche des informations sur tous les partages locaux
    $aInfo = _Net_Share_ShareEnum(@ComputerName)
    MemoWrite("Entries read ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Share name ..............: " & $aInfo[$iI][0])
        MemoWrite("Share type...............: " & _Net_Share_ResourceStr($aInfo[$iI][1]))
        MemoWrite("Comment .................: " & $aInfo[$iI][2])
        MemoWrite("Permissions .............: " & _Net_Share_PermStr($aInfo[$iI][3]))
        MemoWrite("Maximum connections .....: " & $aInfo[$iI][4])
        MemoWrite("Current connections .....: " & $aInfo[$iI][5])
        MemoWrite("Local path ..............: " & $aInfo[$iI][6])
        MemoWrite("Password ................: " & $aInfo[$iI][7])
        MemoWrite()
    Next

    ; Supprime le partage
    _Net_Share_ShareDel(@ComputerName, $sShareName)
    If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur de suppression du partage: " & @error)
    MemoWrite("Partage supprim�")

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contr�le Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite