UDF > WinAPIEx > Dialog >

_WinAPI_FormatDriveDlg

Ouvre la bo�te de dialogue Formatage de Shell

#include <WinAPIDlg.au3>
_WinAPI_FormatDriveDlg ( $sDrive [, $iOption = 0 [, $hParent = 0]] )

Param�tres

$sDrive Le lecteur � formater, au format D:, E:, etc
$iOption [optionnel] Ce param�tre doit �tre 0 ou l'une des valeurs suivantes qui modifient les options de formatage par d�faut dans la bo�te de dialogue.
    $SHFMT_OPT_FULL ( par d�faut )
    $SHFMT_OPT_QUICKFORMAT
    $SHFMT_OPT_SYSONLY
$hParent [optionnel] Handle de la fen�tre parent de la bo�te de dialogue.

Valeur de retour

Succ�s: Retourne l'identifiant de formatage du dernier formatage r�ussi. Le LOWORD de cette valeur peut �tre transmis lors des appels ult�rieurs dans le param�tre fmtID afin de r�p�ter le dernier formatage.
�chec: Retourne 0 et d�finit @error � une des constantes suivantes:
    $SHFMT_ERROR
    $SHFMT_CANCEL
    $SHFMT_NOFORMAT

Remarque

Le format est contr�l� par l'interface de dialogue.
Autrement dit, l'utilisateur doit cliquer sur le bouton OK pour commencer effectivement le formatage--le formatage ne peut pas �tre d�marr�e par programme.

Voir aussi

Consultez SHFormatDrive dans la librairie MSDN.

Exemple

#include <Array.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIDlg.au3>

Local $hForm = GUICreate('Test '& StringReplace(@ScriptName, '.au3', '()'), 200, 100)
Local $vDrive = DriveGetDrive('ALL')
$vDrive = StringUpper(_ArrayToString($vDrive, '|', 1))
GUICtrlCreateLabel('Select drive:', 15, 29, 62, 14)
Local $idCombo = GUICtrlCreateCombo('', 79, 25, 40, 21, $CBS_DROPDOWNLIST)
GUICtrlSetData(-1, $vDrive, StringLeft($vDrive, 2))
Local $idButton = GUICtrlCreateButton('Format...', 65, 70, 70, 23)
GUISetState(@SW_SHOW)

Local $iMsg
Do
    $iMsg = GUIGetMsg()
    if $iMsg = $idButton Then
        _WinAPI_FormatDriveDlg(GUICtrlRead($idCombo), 0, $hForm)
    EndIf
Until $iMsg = $GUI_EVENT_CLOSE