UDF > WinAPIEx > ShellEx >

_WinAPI_RemoveWindowSubclass

Supprime une sous-classe de rappel d'une fen�tre

#include <WinAPIShellEx.au3>
_WinAPI_RemoveWindowSubclass ( $hWnd, $pSubclassProc, $idSubClass )

Param�tres

$hWnd Handle de la fen�tre en cours de sous-classement.
$pSubclassProc Un pointeur vers une proc�dure de fen�tre. Ce pointeur et l'ID de sous-classe identifient de mani�re unique la sous-classe de rappel.
(Voir MSDN pour plus d'informations)
$idSubClass L'ID de sous-classe.

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Voir aussi

Consultez RemoveWindowSubclass dans la librairie MSDN.

Exemple

#include <Extras\WMDebug.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIShellEx.au3>

OnAutoItExitRegister('OnAutoItExit')

; Cr�e une GUI
Global $g_hForm = GUICreate('Test ' & StringReplace(@ScriptName, '.au3', '()'))

; Enregistre une fonction de rappel DLL qui sera utilis�e en tant que proc�dure de sous-classe de fen�tre
Global $g_hDll = DllCallbackRegister('_SubclassProc', 'lresult', 'hwnd;uint;wparam;lparam;uint_ptr;dword_ptr')
Global $g_pDll = DllCallbackGetPtr($g_hDll)

; Installe le rappel de la sous-classe de fen�tre
_WinAPI_SetWindowSubclass($g_hForm, $g_pDll, 1000, 0)

GUISetState(@SW_SHOW)

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _SubclassProc($hWnd, $iMsg, $wParam, $lParam, $iID, $pData)
    #forceref $iID, $pData
    ; D�clar�e dans WMDebug.au3
    _WM_Debug($hWnd, $iMsg, $wParam, $lParam)
    Return _WinAPI_DefSubclassProc($hWnd, $iMsg, $wParam, $lParam)
EndFunc   ;==>_SubclassProc

Func OnAutoItExit()
    _WinAPI_RemoveWindowSubclass($g_hForm, $g_pDll, 1000)
    DllCallbackFree($g_hDll)
EndFunc   ;==>OnAutoItExit