#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; Pour la constante $TRAY_ICONSTATE_SHOW.

Opt("TrayMenuMode", 3) ; Les items de menu de la zone de notification, par d�faut, ne seront pas affich�s et les items ne seront pas coch�s lorsqu'ils seront  s�lectionn�s. Ce sont les options 1 et 2 de TrayMenuMode.

Example()

Func Example()
    Local $idGetText = TrayCreateItem("Get 'About' Text")
    TrayCreateItem("") ; Cr�e une ligne de s�paration.

    Local $idAbout = TrayCreateItem("About")
    TrayCreateItem("") ; Cr�e une ligne de s�paration.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu dans la zone de notification.

    Local $iASlash, $sPath, $iMsg = TrayGetMsg()
    While $iMsg <> $idExit
        Switch $iMsg
            Case $idAbout 
                ; Affiche une bo�te de message � propos de la version et 
                ; du chemin d'installation de l'ex�cutable AutoIt.

                ; Recherche de droite � gauche l'antislash qui marque la fin du chemin
                $iASlash = StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1)
                ; Extrait le chemin seul, sans le nom, ni '\'
                $sPath = StringLeft(@AutoItExe, $iASlash - 1)

                MsgBox($MB_SYSTEMMODAL, "", "Exemple de menu dans la zone de notification." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Chemin d'installation: " & $sPath) 

            Case $idGetText
                ; Affiche une bo�te de message avec le texte de l'�l�ment 'About'.
                MsgBox($MB_SYSTEMMODAL, "", "Le texte de l'�l�ment 'About' est: " & TrayItemGetText($idAbout))

        EndSwitch

        $iMsg = TrayGetMsg()
    WEnd
EndFunc   ;==>Example