UDF > GDIPlus > Graphics >


_GDIPlus_GraphicsGetCompositingMode

Obtient le mode de composition courant install� pour l'objet Graphics

#include <GDIPlus.au3>
_GDIPlus_GraphicsGetCompositingMode ( $hGraphics )

Param�tre

$hGraphics Handle de l'objet Graphics

Valeur de retour

Succ�s: Retourne le mode de composition :
        0 - Indique que lorsqu'une couleur est affich�e, elle est m�lang�e avec la couleur de fond
        1 - Indique que lorsqu'une couleur est affich�e, elle remplace la couleur de fond
�chec: Retourne -1 et d�finit @error <> 0, @extended GPSTATUS contient un code d'erreur ($GPID_ERR*).

Remarque

En relation

_GDIPlus_GraphicsSetCompositingMode

Voir aussi

Consultez GdipGetCompositingMode dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBitmap, $hContext, $hBrush, $iMode1, $iMode2

    ; Cr�e GUI
    $hGUI = GUICreate("GDI+", 800, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Cr�e un objet graphique � partir d'un handle fen�tre
    $hBitmap = _GDIPlus_BitmapCreateFromScan0(800, 400)
    $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)

    $hBrush = _GDIPlus_LineBrushCreate(0, 0, 0, 400, 0xFF0000FF, 0)

    _GDIPlus_GraphicsFillRect($hContext, 10, 10, 300, 300, $hBrush)
    _GDIPlus_GraphicsFillRect($hContext, 80, 60, 300, 300, $hBrush)
    $iMode1 = _GDIPlus_GraphicsGetCompositingMode($hContext)

    _GDIPlus_GraphicsSetCompositingMode($hContext, $GDIP_CompositingModeSourceCopy)
    _GDIPlus_GraphicsFillRect($hContext, 420, 10, 300, 300, $hBrush)
    _GDIPlus_GraphicsFillRect($hContext, 490, 60, 300, 300, $hBrush)
    $iMode2 = _GDIPlus_GraphicsGetCompositingMode($hContext)

    _GDIPlus_GraphicsClear($hGraphic, 0xFFFFFFFF)
    _GDIPlus_GraphicsDrawImage($hGraphic, $hBitmap, 0, 0)

    _GDIPlus_GraphicsDrawString($hGraphic, "CompositingMode = " & $iMode1, 10, 380)
    _GDIPlus_GraphicsDrawString($hGraphic, "CompositingMode = " & $iMode2, 420, 380)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hContext)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example