#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIGdi.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    Local $hGUI, $hPath, $hFamily, $tLayout, $aSize, $hRegion, $hRGN

    _GDIPlus_Startup()

    $hGUI = GUICreate("GDI+", 620, 100)
    GUISetBkColor(0x80) ; R�gle la couleur de fond de la fen�tre � bleu
    GUISetState(@SW_SHOW)

    $hPath = _GDIPlus_PathCreate() ; Cr�e un objet path

    $hFamily = _GDIPlus_FontFamilyCreate("Arial Black") ; Cr�e un objet FontFamily
    $tLayout = _GDIPlus_RectFCreate() ; Cr�e une cha�ne d�limit�e par un rectangle de position X=0, Y=0
    _GDIPlus_PathAddString($hPath, "AutoIt rulez!", $tLayout, $hFamily, 0, 85, 0) ; Ajoute le contour de la cha�ne au Path

    $aSize = WinGetPos($hGUI) ; Obtient windowsize

    $hRegion = _GDIPlus_RegionCreateFromRect(0, 0, 110, $aSize[3]) ; Cr�e une r�gion � partir d'un rectangle
    _GDIPlus_RegionCombineRect($hRegion, $aSize[2] - 110, 0, 110, $aSize[3], 2) ; Combine rectangle_left ET rectangle_right
    _GDIPlus_RegionCombinePath($hRegion, $hPath, 3) ; Combine- XOR les rectangles contenant les cha�nes

    $hRGN = _GDIPlus_RegionGetHRgn($hRegion, 0) ; Cr�e une r�gion GDI � partir de la r�gion GDI+
    _WinAPI_SetWindowRgn($hGUI, $hRGN) ; D�finit une r�gion partie de la fen�tre

    ; Boucle jusqu'� ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_FontFamilyDispose($hFamily)
    _WinAPI_DeleteObject($hRGN)
    _GDIPlus_RegionDispose($hRegion)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example