UDF > GUI > GuiHeader >

_GUICtrlHeader_SetItemFormat

D�finit le format d'un �l�ment

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemFormat ( $hWnd, $iIndex, $iFormat )

Param�tres

$hWnd Handle du contr�le
$iIndex Index de l'�l�ment, compt� � partir de 0
$iFormat Combinaison des identificateurs de format suivants:
    $HDF_CENTER - Le contenu de l'�l�ment est centr�
    $HDF_LEFT - le contenu de l'�l�ment est align� � gauche
    $HDF_RIGHT - Le contenu de l'�l�ment est align� � droite
    $HDF_BITMAP - L'�l�ment affiche une image bitmap
    $HDF_BITMAP_ON_RIGHT - Le bitmap appara�t � droite du texte
    $HDF_OWNERDRAW - Le propri�taire du contr�le Header dessine l'�l�ment
    $HDF_STRING - L'�l�ment affiche une cha�ne
    $HDF_IMAGE - Affiche une image � partir d'une liste d'images
    $HDF_RTLREADING - Le texte sera lu dans la direction oppos�e par rapport au texte de la fen�tre parent
    $HDF_SORTDOWN - Dessine une fl�che vers le bas sur cet �l�ment
    $HDF_SORTUP - Dessine une fl�che vers le haut sur cet �l�ment

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

En relation

_GUICtrlHeader_GetItemFormat

Exemple

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $hHeader, $hImage

    ; Cr�e une GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
    $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Cr�e une liste d'images avec des images
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; Ajoute des colonnes
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; D�finit le format de la colonne 1
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_CENTER, $HDF_STRING))

    ; Montre le format de la colonne 1
    MemoWrite("Column 1 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    Sleep(1000)

    ; D�finit le format de la colonne 1
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_LEFT, $HDF_STRING, $HDF_IMAGE))

    ; Montre le format de la colonne 1
    MemoWrite("Column 1 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contr�le m�mo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite