UDF > GUI > GuiMenu >

_GUICtrlMenu_CreateMenu

Cr�e un menu

#include <GuiMenu.au3>
_GUICtrlMenu_CreateMenu ( [$iStyle = $MNS_CHECKORBMP] )

Param�tre

$iStyle [optionnel] Style du menu. Peut prendre une ou plusieurs des valeurs suivantes:
    $MNS_AUTODISMISS - Le menu se termine automatiquement lorsque la souris reste en dehors du menu pendant 10 secondes
    $MNS_CHECKORBMP - Le m�me espace est r�serv� pour la case � cocher et le bitmap (option par d�faut)
    $MNS_DRAGDROP - Les �l�ments du menu sont cibles d'un Drop OLE ou sources d'un Drag
    $MNS_MODELESS - Le menu est une bo�te modale
    $MNS_NOCHECK - Pas d'espace r�serv� � gauche d'un �l�ment pour une case � cocher
    $MNS_NOTIFYBYPOS - Le propri�taire du menu re�oit un message WM_MENUCOMMAND au lieu d'un message WM_COMMAND pour les s�lections

Valeur de retour

Succ�s: Retourne le handle du menu cr��.
�chec: Retourne 0.

Remarque

Les ressources de menu qui sont affect�s � une fen�tre sont lib�r�s automatiquement. Si le menu n'est pas affect� � une fen�tre, une application doit lib�rer les ressources syst�me associ�es au menu avant la fermeture.
Une application lib�re les ressources d'un menu en appelant la fonction _GUICtrlMenu_DestroyMenu().
$MNS_NOTIFYBYPOS est un style d'en-t�te de menu et n'a aucun effet lorsqu'elle est appliqu�e � des sous-menus

En relation

_GUICtrlMenu_CreatePopup, _GUICtrlMenu_DestroyMenu

Voir aussi

Consultez CreateMenu dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
#include <WinAPIConv.au3>
#include <WindowsConstants.au3>

Global $g_idMemo
Global Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain

    ; Cr�e une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Cr�e un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Cr�e un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Cr�e un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Cr�e un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Affecte le menu � la fen�tre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)

    ; Cr�e un contr�le m�mo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; R�pond aux �v�nements du menu
Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    Switch _WinAPI_LoWord($wParam)
        Case $e_idNew
            MemoWrite("New")
        Case $e_idOpen
            MemoWrite("Open")
        Case $e_idSave
            MemoWrite("Save")
        Case $e_idExit
            Exit
        Case $e_idCut
            MemoWrite("Cut")
        Case $e_idCopy
            MemoWrite("Copy")
        Case $e_idPaste
            MemoWrite("Paste")
        Case $e_idAbout
            MemoWrite("About")
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

; Ecrit un message dans le contr�le m�mo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite