UDF > GUI > GuiMenu >

_GUICtrlMenu_InsertMenuItem

Ins�re un nouvel �l�ment de menu � la position sp�cifi�e

#include <GuiMenu.au3>
_GUICtrlMenu_InsertMenuItem ( $hMenu, $iIndex, $sText [, $iCmdID = 0 [, $hSubMenu = 0]] )

Param�tres

$hMenu Handle du contr�le Menu
$iIndex Position de l'�l�ment de menu de base de 0, avant lequel ins�rer le nouvel �l�ment
$sText Texte de l'�l�ment de manu. Si vide, un s�parateur est ins�r�.
$iCmdID [optionnel] ID de commande � attribuer � l'�l�ment
$hSubMenu [optionnel] Handle du sous-menu associ� � l'�l�ment de menu

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

En relation

_GUICtrlMenu_AddMenuItem, _GUICtrlMenu_AppendMenu, _GUICtrlMenu_InsertMenuItemEx

Voir aussi

Consultez InsertMenuItem dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste

    ; Cr�e une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Cr�e un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Cr�e un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Cr�e un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()

    ; Cr�e un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu � la fen�tre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example