UDF > NetShare >

_Net_Share_ShareSetInfo

Partage d'une ressource de serveur

#include <NetShare.au3>
_Net_Share_ShareSetInfo ( $sServer, $sShare, $sComment, $iMaxUses )

Param�tres

$sServer Indique le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'ex�cute.
Si ce param�tre est vide, l'ordinateur local est utilis�.
$sShare Nom du partage dont vous voulez d�finir des informations
$sComment Cha�ne qui contient un commentaire optionnel sur la ressource partag�e
$iMaxUses Nombre maximal de connexions que la ressource peut accueillir.
Le nombre de connexions est illimit� si cette valeur est -1.

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Remarque

L'appartenance � un groupe Administrateurs, Utilisateurs, Op�rateurs d'impression, ou Op�rateurs pour serveurs, est n�cessaire pour ex�cuter cette fonction.
Un op�rateur d'impression peut d�finir uniquement des informations sur les paratges d'imprimante.

En relation

_Net_Share_ShareGetInfo

Voir aussi

Consultez NetShareSetInfo dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

#RequireAdmin ; n�cessaire pour _Net_Share_ShareAdd()

Global $g_idMemo

Example()

Func Example()
    Local $aInfo
    Local Const $sShareName = "AutoIt Share"

    ; Cr�e une GUI
    GUICreate("NetShare", 400, 300)

    ; Cr�e un contr�le Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Teste si le partage existe
    If _Net_Share_ShareCheck(@ComputerName, $sShareName) = -1 Then
        ; Cr�ez un partage sur l'ordinateur local
        _Net_Share_ShareAdd(@ComputerName, $sShareName, 0, "C:\", "AutoIt Share Comment")
        If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Share add error : " & @error)
        MemoWrite("Share added")
    Else
        MemoWrite("Share exists")
    EndIf

    ; Modifie les informations du partage
    _Net_Share_ShareSetInfo(@ComputerName, $sShareName, "New Comment", 4)

    ; Affiche des informations sur l'action, nous avons ajout�
    $aInfo = _Net_Share_ShareGetInfo(@ComputerName, $sShareName)
    MemoWrite("Share name ..............: " & $aInfo[0])
    MemoWrite("Share type...............: " & _Net_Share_ResourceStr($aInfo[1]))
    MemoWrite("Comment .................: " & $aInfo[2])
    MemoWrite("Permissions .............: " & _Net_Share_PermStr($aInfo[3]))
    MemoWrite("Maximum connections .....: " & $aInfo[4])
    MemoWrite("Current connections .....: " & $aInfo[5])
    MemoWrite("Local path ..............: " & $aInfo[6])
    MemoWrite("Password ................: " & $aInfo[7])

    ; Supprime le partage
    _Net_Share_ShareDel(@ComputerName, $sShareName)
    If @error Then MsgBox($MB_SYSTEMMODAL, "Information", "Erreur dans la suppression du partage: " & @error)
    MemoWrite("Partage supprim�")

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contr�le Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite