Functions > GUI > GUICtrlCreate >

GUICtrlCreateGraphic

Cr�e un contr�le Graphic pour une GUI.

GUICtrlCreateGraphic ( left, top [, width [, height [, style]]] )

Param�tres

left Coordonn�e X du coin sup�rieur gauche du contr�le. Si vous utilisez -1, X sera calcul�e en accord avec GUICoordMode.
top Coordonn�e Y du coin sup�rieur gauche du contr�le. Si vous utilisez -1, Y sera calcul�e en accord avec GUICoordMode.
width [optionnel] Largeur du contr�le (par d�faut, la largeur utilis�e pr�c�demment).
height [optionnel] Hauteur du contr�le (par d�faut, la hauteur utilis�e pr�c�demment).
style [optionnel] D�finit le style du contr�le. Consultez l'Annexe de styles de contr�le GUI.
    Par d�faut (-1) : $SS_NOTIFY.

Valeur de retour

Succ�s: Retourne l'ID du nouveau contr�le.
�chec: Retourne 0.

Remarques

Pour dessiner dans le contr�le, consultez GUICtrlSetGraphic.

La couleur du contour et la couleur de fond peuvent �tre d�finies avec GUICtrlSetBkColor() et GUICtrlSetColor().

Le contr�le graphique peut �tre cliqu� donc il ne devrait pas recouvrir d'autres contr�les. Si le recouvrement est n�cessaire, il est important de d�sactiver le contr�le graphique: GUICtrlSetState(-1, $GUI_DISABLE).

Ce contr�le ne peut pas �tre redimensionn� en raison d'une correction relative � l'adressage lors de sa cr�ation, mais il peut �tre attach� avec GUICtrlSetResizing().

En relation

GUICoordMode (Option), GUICtrlDelete, GUICtrlSetBkColor, GUICtrlSetColor, GUICtrlSetGraphic, GUICtrlSetResizing, GUICtrlSetStyle, GUIGetMsg

Exemple

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>

Global Const $g_MAXGr = 6
Global $g_a_idArray[$g_MAXGr + 1] ; 0 et les entr�es $g_MAXGr ne sont pas utilis�s pour permettre le r�sultat de GUICtrlDelete
Global $g_idDel

Example()

Func Example()
    Local $idMsg, $iInc, $i

    CreateChild()

    $i = 1
    $iInc = 1
    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
        $idMsg = GUIGetMsg()

        If $idMsg = $g_idDel Then
            GUICtrlDelete($g_a_idArray[$i])
            $i = $i + $iInc
            If $i < 0 Or $i > $g_MAXGr Then Exit
        EndIf
        If $idMsg > 0 Then MsgBox($MB_SYSTEMMODAL, "cliqu�", $idMsg & @CRLF & $g_a_idArray[5], 2)
    Until $idMsg = $GUI_EVENT_CLOSE

EndFunc   ;==>Example

Func CreateChild()
    GUICreate("My Draw")
    $g_idDel = GUICtrlCreateButton("Delete", 50, 165, 50)

    $g_a_idArray[1] = GUICtrlCreateGraphic(20, 50, 100, 100)
    GUICtrlSetBkColor(-1, 0xffffff)
    GUICtrlSetColor(-1, 0)

    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff0000, 0xff0000)
    GUICtrlSetGraphic(-1, $GUI_GR_PIE, 50, 50, 40, 30, 270)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x00ff00, 0xffffff)
    GUICtrlSetGraphic(-1, $GUI_GR_PIE, 58, 50, 40, -60, 90)

    GUICtrlSetGraphic(-1, $GUI_GR_ELLIPSE, 100, 100, 50, 80)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x00ff00, 0xc0c0ff)
    GUICtrlSetGraphic(-1, $GUI_GR_RECT, 350, 200, 50, 80)
    GUICtrlCreateLabel("label", 65, 100, 30)
    GUICtrlSetColor(-1, 0xff)

    $g_a_idArray[2] = GUICtrlCreateGraphic(220, 50, 100, 100)
    GUICtrlSetStyle(-1, $SS_NOTIFY)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0, 0xff)
    GUICtrlSetGraphic(-1, $GUI_GR_PIE, 50, 50, 40, 30, 270)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x00ff00, 0xffffff)
    GUICtrlSetGraphic(-1, $GUI_GR_PIE, 58, 50, 40, -60, 90)

    $g_a_idArray[3] = GUICtrlCreateGraphic(220, 150, 100, 100, 0)
    GUICtrlSetBkColor(-1, 0xf08080)
    GUICtrlSetColor(-1, 0xff)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff00)
    GUICtrlSetGraphic(-1, $GUI_GR_RECT, 50, 50, 80, 80)

    $g_a_idArray[4] = GUICtrlCreateGraphic(20, 200, 80, 80)
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlSetBkColor(-1, 0xffffff)
    GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 10, 10)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff)
    GUICtrlSetGraphic(-1, $GUI_GR_LINE, 30, 40)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff00)
    GUICtrlSetGraphic(-1, $GUI_GR_LINE, 70, 70)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff0000)
    GUICtrlSetGraphic(-1, $GUI_GR_LINE, 10, 50)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xffff00)
    GUICtrlSetGraphic(-1, $GUI_GR_LINE, 10, 10)

    $g_a_idArray[5] = GUICtrlCreateGraphic(150, 10, 50, 50, 0)
    GUICtrlSetBkColor(-1, 0xa0ffa0)
    GUICtrlSetGraphic(-1, $GUI_GR_MOVE, 20, 20) ; le point de d�part
    ; Il est pr�f�rable de tracer une ligne et apr�s le point
    ; pour �viter de permuter la couleur � chaque dessin
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0x0000ff)
    GUICtrlSetGraphic(-1, $GUI_GR_DOT, 30, 30)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0)
    GUICtrlSetGraphic(-1, $GUI_GR_LINE, 20, 40)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0xff0000)
    GUICtrlSetGraphic(-1, $GUI_GR_DOT, 25, 25)
    GUICtrlSetGraphic(-1, $GUI_GR_COLOR, 0)
    GUICtrlSetGraphic(-1, $GUI_GR_LINE, 40, 40)
    GUICtrlSetGraphic(-1, $GUI_GR_DOT, 40, 40)

    GUISetState(@SW_SHOW)
EndFunc   ;==>CreateChild