UDF > GDIPlus > Image >

_GDIPlus_ImageLoadFromStream

Cr�e un objet Image � partir d'un flux

#include <GDIPlus.au3>
_GDIPlus_ImageLoadFromStream ( $pStream )

Param�tre

$pStream Handle de l'interface IStream

Valeur de retour

Succ�s: Retourne le handle de l'objet Image.
�chec: Retourne 0 et d�finit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Lorsque vous en avez termin� avec l'objet, appelez _GDIPlus_ImageDispose() pour lib�rer les ressources de l'objet.

En relation

_GDIPlus_ImageDispose

Voir aussi

Consultez GdipLoadImageFromStream dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPICom.au3>
#include <WinAPIConv.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local Const $iW = @DesktopWidth / 2, $iH = @DesktopHeight / 2
    Local $hGUI = GUICreate("GDI+ test", $iW, $iH, -1, -1)
    GUISetState(@SW_SHOW)

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, @DesktopWidth / 2, @DesktopHeight / 2) ; Cr�e un bitmap GDI en capturant un quart de bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Lib�re la ressource du bitmap GDI car elle n'est plus utile

    Local $sImgCLSID = _GDIPlus_EncodersGetCLSID("jpg") ; Cr�e le CLSID pour un type JPG de fichier d'image
    Local $tGUID = _WinAPI_GUIDFromString($sImgCLSID) ; Convertit CLSID GUID sous forme binaire et retourne la structure $tagGUID
    Local $pEncoder = DllStructGetPtr($tGUID) ; Obtient le handle de la structure $tagGUID
    Local $tParams = _GDIPlus_ParamInit(1) ; Initialise une liste de param�tres de l'encodeur et retourne la structure  $tagGDIPENCODERPARAMS
    Local $tData = DllStructCreate("int Quality") ; Cr�e une structure pour d�finir le degr� de qualit� JPG
    DllStructSetData($tData, "Quality", 10) ; Qualit� 0-100 (0 : plus bas, 100 : le plus �lev�)
    Local $pData = DllStructGetPtr($tData) ; Obtient le handle de la structure de qualit�
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData) ; Ajoute une valeur � la liste de param�tres de l'encodeur
    Local $pParams = DllStructGetPtr($tParams) ; Obtient le handle de la liste des param�tres de l'encodeur 
    Local $pStream = _WinAPI_CreateStreamOnHGlobal() ; Cr�e le flux
    _GDIPlus_ImageSaveToStream($hBitmap, $pStream, $pEncoder, $pParams) ; Enregistre l'image au format JPG dans la m�moire
    Local $hImageFromStream = _GDIPlus_ImageLoadFromStream($pStream) ; Cr�e le bitmap � partir du flux (ici du JPG en m�moire)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Cr�e un objet Graphics � partir du handle de la fen�tre
    _GDIPlus_GraphicsDrawImage($hGraphics, $hImageFromStream, 0, 0) ; Affiche l'image en streaming

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE 

    ; Efface les ressources
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_ImageDispose($hImageFromStream)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example