UDF > GDIPlus > Image >

_GDIPlus_ImageSaveToStream

Enregistre un objet Image dans un flux

#include <GDIPlus.au3>
_GDIPlus_ImageSaveToStream ( $hImage, $pStream, $tEncoder [, $tParams = 0] )

Param�tres

$hImage Handle de l'objet Image
$pStream Handle de l'interface IStream
$tEncoder Une structure $tagGUID qui d�finit le GUID de l'encodeur d'image
$tParams [optionnel] Une structure $tagGDIPENCODERPARAMS ou un pointeur sur une telle structure

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False et d�finit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

Remarque

Utilisez cette fonction pour enregistrer des trames s�lectionn�es � partir d'une image � trames multiples vers une autre image � trames multiples.

En relation

$tagGDIPENCODERPARAMS, _GDIPlus_EncodersGetCLSID, _GDIPlus_ImageLoadFromStream, _GDIPlus_ImageSaveToFile

Voir aussi

Consultez GdipSaveImageToStream dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPICom.au3>
#include <WinAPIConv.au3>
#include <WinAPIHObj.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local Const $iW = @DesktopWidth / 2, $iH = @DesktopHeight / 2
    Local $hGUI = GUICreate("GDI+ test", $iW, $iH, -1, -1)
    GUISetState(@SW_SHOW)

    Local $hHBmp = _ScreenCapture_Capture("", 0, 0, @DesktopWidth / 2, @DesktopHeight / 2) ; Cr�e un bitmap GDI en capturant un quart de bureau
    Local $hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hHBmp) ; Convertit le bitmap GDI en GDI+
    _WinAPI_DeleteObject($hHBmp) ; Lib�re la ressource du bitmap GDI car elle n'est plus utile

    Local $sImgCLSID = _GDIPlus_EncodersGetCLSID("jpg") ; Cr�e le CLSID pour un type JPG de fichier d'image
    Local $tGUID = _WinAPI_GUIDFromString($sImgCLSID) ; Convertit le GUID du CLSID sous forme binaire et retourne la structure $tagGUID
    Local $pEncoder = DllStructGetPtr($tGUID) ; Obtient le pointeur sur la structure $tagGUID
    Local $tParams = _GDIPlus_ParamInit(1) ; Initialise une liste de param�tres de l'encodeur et retourne la structure  $tagGDIPENCODERPARAMS
    Local $tData = DllStructCreate("int Quality") ; Cr�e la struct pour d�finir le degr� de qualit� JPG
    DllStructSetData($tData, "Quality", 10) ; Qualit� 0-100 (0 : plus bas, 100 : le plus �lev�)
    Local $pData = DllStructGetPtr($tData) ; Obtient le pointeur sur la struct de qualit�
    _GDIPlus_ParamAdd($tParams, $GDIP_EPGQUALITY, 1, $GDIP_EPTLONG, $pData) ; Ajoute une valeur � la liste des param�tres de l'encodeur
    Local $pParams = DllStructGetPtr($tParams) ; Obtient le pointeur sur la liste des param�tres de l'encodeur
    Local $pStream = _WinAPI_CreateStreamOnHGlobal() ; Cr�e un flux
    _GDIPlus_ImageSaveToStream($hBitmap, $pStream, $pEncoder, $pParams) ; Enregistre l'image au format JPG dans la m�moire
    Local $hBitmapFromStream = _GDIPlus_BitmapCreateFromStream($pStream) ; Cr�e le bitmap � partir du flux (ici du JPG en m�moire)

    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ; Cr�e un objet Graphics � partir du handle de la fen�tre
    _GDIPlus_GraphicsDrawImage($hGraphics, $hBitmapFromStream, 0, 0) ; Affiche l'image en streaming

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE 

    ; Nettoie les ressources
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_BitmapDispose($hBitmapFromStream)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example