UDF > GUI > GuiMenu >

_GUICtrlMenu_AddMenuItem

Ajoute un nouvel �l�ment de menu � la fin d'un menu

#include <GuiMenu.au3>
_GUICtrlMenu_AddMenuItem ( $hMenu, $sText [, $iCmdID = 0 [, $hSubMenu = 0]] )

Param�tres

$hMenu Handle du contr�le Menu
$sText Texte de l'�l�ment. Si vide, un trait de s�paration sera ajout� au menu.
$iCmdID [optionnel] ID de commande � attribuer � l'�l�ment
$hSubMenu [optionnel] Handle du sous-menu associ� � l'�l�ment de menu

Valeur de retour

Succ�s: Retourne l'index de l'�l�ment de menu, de base 0.
�chec: Retourne -1.

En relation

_GUICtrlMenu_InsertMenuItem

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Cr�e une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Cr�e un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hFile, "&New", $e_idNew)
    _GUICtrlMenu_AddMenuItem($hFile, "&Open", $e_idOpen)
    _GUICtrlMenu_AddMenuItem($hFile, "&Save", $e_idSave)
    _GUICtrlMenu_AddMenuItem($hFile, "", 0)
    _GUICtrlMenu_AddMenuItem($hFile, "E&xit", $e_idExit)

    ; Cr�e un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hEdit, "&Cut", $e_idCut)
    _GUICtrlMenu_AddMenuItem($hEdit, "C&opy", $e_idCopy)
    _GUICtrlMenu_AddMenuItem($hEdit, "&Paste", $e_idPaste)

    ; Cr�e un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hHelp, "&About", $e_idAbout)

    ; Cr�e un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_AddMenuItem($hMain, "&File", 0, $hFile)
    _GUICtrlMenu_AddMenuItem($hMain, "&Edit", 0, $hEdit)
    _GUICtrlMenu_AddMenuItem($hMain, "&Help", 0, $hHelp)

    ; Attache le menu � la fen�tre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example