UDF > GUI > GuiToolTip >

_GUIToolTip_TrackActivate

Active ou d�sactive un contr�le info-bulle qui suit la souris

#include <GuiToolTip.au3>
_GUIToolTip_TrackActivate ( $hWnd [, $bActivate = True [, $hTool = 0 [, $iID = 0]]] )

Param�tres

$hWnd Handle du contr�le info-bulle (retourn� par _GUIToolTip_Create.)
$bActivate [optionnel] True pour activer, false pour d�sactiver
$hTool [optionnel] Handle de la fen�tre qui contient l'�l�ment
$iID [optionnel] Handle du contr�le auquel l'�l�ment est assign�, ou identifiant de l'�l�ment d�fini par l'application

Valeur de retour

Aucune.

Remarque

Vous devez utiliser cette fonction pour activer une info-bulle qui traque la souris avant de mettre � jour sa position � l'aide de _GUIToolTip_TrackPosition().
Si vous utilisez _GUIToolTip_TrackPosition() sans utiliser _GUIToolTip_TrackActivate() alors l'�l�ment s'affichera uniquement lorsque la souris survolera la fen�tre ou le contr�le assign�, le cas �ch�ant.

En relation

_GUIToolTip_TrackPosition

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $hToolTip = _GUIToolTip_Create(0, $TTS_BALLOON)
    ; Ajoute au contr�le info-bulle, sans utiliser de contr�le ou de GUI pour l'y associer
    _GUIToolTip_AddTool($hToolTip, 0, " ", 0, 0, 0, 0, 0, $TTF_SUBCLASS)

    _GUIToolTip_SetTitle($hToolTip, 'Mouse position', $TTI_INFO)
    GUISetState(@SW_SHOW)

    _GUIToolTip_TrackActivate($hToolTip, True, 0, 0)
    Local $aPos, $iOldaPos0, $iOldaPos1
    
    Do
        Sleep(10)
        $aPos = MouseGetPos()
        If $aPos[0] <> $iOldaPos0 Or $aPos[1] <> $iOldaPos1 Then
            _GUIToolTip_TrackPosition($hToolTip, $aPos[0] + 10, $aPos[1] + 20)
            _GUIToolTip_UpdateTipText($hToolTip, 0, 0, "X: " & $aPos[0] & " Y: " & $aPos[1])
            $iOldaPos0 = $aPos[0]
            $iOldaPos1 = $aPos[1]  
        EndIf
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    
    ; D�truit le contr�le info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example