UDF > GUI > GuiToolTip >

_GUIToolTip_TrackPosition

D�finit la position d'un contr�le info-bulle qui suit la souris

#include <GuiToolTip.au3>
_GUIToolTip_TrackPosition ( $hWnd, $iX, $iY )

Param�tres

$hWnd Handle du contr�le info-bulle (retourn� par _GUIToolTip_Create.)
$iX Position X en coordonn�es d'�cran
$iY Position Y en coordonn�es d'�cran

Valeur de retour

Aucune.

Remarque

Avec cette fonction, l'info-bulle affichera la fen�tre � partir des coordonn�es que vous fournissez.
Vous devez utiliser _GUIToolTip_TrackActivate() en combinaison avec _GUIToolTip_TrackPosition() sinon cette fonction n'a aucun effet sur l'info-bulle.

En relation

_GUIToolTip_TrackActivate

Exemple

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton(" Button ", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)

    Local $hToolTip = _GUIToolTip_Create($hGUI, BitOR($_TT_ghTTDefaultStyle, $TTS_BALLOON))

    _GUIToolTip_AddTool($hToolTip, 0, " ", $hButton)

    _GUIToolTip_SetTitle($hToolTip, 'Mouse position', $TTI_INFO)
    GUISetState(@SW_SHOW)
    ; Cherche la position de la souris pour l'utiliser comme point de d�part pour le tracking
    Local $aPos = MouseGetPos()
    _GUIToolTip_TrackPosition($hToolTip, $aPos[0], $aPos[1])
    _GUIToolTip_TrackActivate($hToolTip, True, 0, $hButton)

    Do
        ; Lit la position de la souris
        $aPos = MouseGetPos()
        ; Utilise la position de la souris pour d�finir la position du tooltip
        _GUIToolTip_TrackPosition($hToolTip, $aPos[0], $aPos[1])
        _GUIToolTip_UpdateTipText($hToolTip, 0, $hButton, "X: " & $aPos[0] & " Y: " & $aPos[1])
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; D�truit le contr�le info-bulle
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example