UDF > GUI > GuiMenu >

_GUICtrlMenu_CheckMenuItem

Coche/d�coche l'�l�ment du menu sp�cifi�e pour le s�lectionner ou le d�s�lectionner

#include <GuiMenu.au3>
_GUICtrlMenu_CheckMenuItem ( $hMenu, $iItem [, $bCheck = True [, $bByPos = True]] )

Param�tres

$hMenu Handle du contr�le Menu
$iItem Identifiant ou position de l'�l�ment du menu � cocher/d�cocher
$bCheck [optionnel] True pour cocher la case, False pour la d�cocher
$bByPos [optionnel] Indicateur de l'identifiant du Menu:
    True  - $iItem est la position de base 0 de l'�l�ment
    False - $iItem est l'identifiant de l'�l�ment du menu

Valeur de retour

Succ�s: Retourne l'�tat pr�c�dent de l'�l�ment du menu ($MF_CHECKED ou $MF_UNCHECKED).
�chec: Retourne -1.

Remarque

Un �l�ment dans une barre de menu ne peut pas avoir de case � cocher. Le param�tre $iItem identifie un �l�ment qui ouvre un sous-menu ou un �l�ment de commande.
Pour un �l�ment qui ouvre un sous-menu, le param�tre $iItem doit sp�cifier la position de l'�l�ment.
Pour un �l�ment de commande, le param�tre $iItem doit sp�cifier la position ou l'identifiant de l'�l�ment.

En relation

_GUICtrlMenu_CheckRadioItem

Voir aussi

Consultez CheckMenuItem dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Cr�e une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Cr�e un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Cr�e un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Cr�e un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Cr�e un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu � la fen�tre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Coche l'�l�ment de menu About
    _GUICtrlMenu_CheckMenuItem($hHelp, 0)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example