UDF > GUI > GuiMenu >

_GUICtrlMenu_CheckRadioItem

Coche un �l�ment de menu sp�cifi� et en fait un �l�ment radio

#include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem ( $hMenu, $iFirst, $iLast, $iCheck [, $bByPos = True] )

Param�tres

$hMenu Handle du contr�le Menu
$iFirst Identifiant ou position du premier �l�ment de menu dans le groupe
$iLast Identifiant ou position du dernier �l�ment de menu dans le groupe
$iCheck Identifiant ou position de l'�l�ment de menu � cocher
$bByPos [optionnel] Indicateur des identifiants de Menu:
    True  - $iFirst, $iLast et $iCheck sont des positions de base 0 d'�l�ments de menu
    False - $iFirst, $iLast et $iCheck sont des identifiants d'�l�ments de menu

Valeur de retour

Succ�s: Retourne True.
�chec: Retourne False.

Remarque

Cette fonction active l'indicateur $MFT_RADIOCHECK et l'�tat $MFS_CHECKED pour l'�l�ment sp�cifi� par $iCheck et, en m�me temps, d�sactive les indicateurs pour tous les autres �l�ments du groupe. L'�l�ment coch� est affich� en utilisant un bitmap repr�sentant un rond � la place d'un carr�.

En relation

_GUICtrlMenu_CheckMenuItem

Voir aussi

Consultez CheckMenuRadioitem dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>

Example()

Func Example()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout

    ; Cr�e une GUI
    $hGUI = GUICreate("Menu", 400, 300)

    ; Cr�e un menu File
    $hFile = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
    _GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
    _GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
    _GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)

    ; Cr�e un menu Edit
    $hEdit = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
    _GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
    _GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)

    ; Cr�e un menu Help
    $hHelp = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)

    ; Cr�e un menu Main
    $hMain = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
    _GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)

    ; Attache le menu � la fen�tre
    _GUICtrlMenu_SetMenu($hGUI, $hMain)
    GUISetState(@SW_SHOW)

    ; Coche l'�l�ment Open du menu
    _GUICtrlMenu_CheckRadioItem($hFile, 0, 4, 2)

    ; Boucle jusqu'� ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example